The RoLLing cOde

The Hit List is a good task management software for Mac OSX, and I personally think it’s better than OmniFocus and Things.

tell application "Microsoft Outlook"
	set |inbox| to current messages
	repeat with theMessage in |inbox|
		set theTitle to subject of theMessage
		set theNotes to (content of theMessage) & return
		set theID to id of theMessage as string
		set theCommand to "mdfind com_microsoft_entourage_recordID==" & theID
		set theMDfile to the first item of paragraphs of (do shell script theCommand)
		set theDate to time received of theMessage
		tell application "The Hit List"
			tell inbox to set theTask to make new task with properties {title:theTitle & " @email", notes:theNotes, start date:theDate}
			tell notes of theTask to make new attachment with properties {file name:theMDfile} at after the last paragraph
		end tell
		set msgLen to the length of theNotes
		if msgLen > 120 then
			set theNotes to get text 1 through 120 of theNotes
			set theNotes to theNotes & "..."
		end if
		tell application "GrowlHelperApp" to notify with name "New Email" title (theTitle) description (theNotes) application name "Entourage Growl Notifier" priority 0 sticky no icon of application "The Hit List"
	end repeat
end tell

To use this as a mail rule, in Entourage, open menuToolsRules, add a new rule with “Run AppleScript” as its action.

To use this as a menu item or hotkey script, copy the script to ~/Documents/Microsoft User Data/Entourage Script Menu Items/ , it’ll appear in the Script menu of Entourage.You can even add a \cT after it’s name so that it will be triggered when you press Ctrl-T.